Gecko [ www.finalhopeacademy.com ]

Name	Size	Permission
CMakeAddFortranSubdirectory	[ DIR ]	drwxr-xr-x
Compiler	[ DIR ]	drwxr-xr-x
CompilerId	[ DIR ]	drwxr-xr-x
FindCUDA	[ DIR ]	drwxr-xr-x
FortranCInterface	[ DIR ]	drwxr-xr-x
IntelVSImplicitPath	[ DIR ]	drwxr-xr-x
Platform	[ DIR ]	drwxr-xr-x
AddFileDependencies.cmake	1002 B	-rw-r--r--
AutomocInfo.cmake.in	675 B	-rw-r--r--
BasicConfigVersion-AnyNewerVer...	1.34 KB	-rw-r--r--
BasicConfigVersion-ExactVersio...	1.8 KB	-rw-r--r--
BasicConfigVersion-SameMajorVe...	1.69 KB	-rw-r--r--
BundleUtilities.cmake	28.62 KB	-rw-r--r--
CMake.cmake	772 B	-rw-r--r--
CMakeASM-ATTInformation.cmake	1020 B	-rw-r--r--
CMakeASMCompiler.cmake.in	545 B	-rw-r--r--
CMakeASMInformation.cmake	5.28 KB	-rw-r--r--
CMakeASM_MASMInformation.cmake	903 B	-rw-r--r--
CMakeASM_NASMInformation.cmake	1.45 KB	-rw-r--r--
CMakeAddFortranSubdirectory.cm...	7.73 KB	-rw-r--r--
CMakeAddNewLanguage.txt	1.49 KB	-rw-r--r--
CMakeBackwardCompatibilityC.cm...	3.38 KB	-rw-r--r--
CMakeBackwardCompatibilityCXX....	2.12 KB	-rw-r--r--
CMakeBorlandFindMake.cmake	736 B	-rw-r--r--
CMakeBuildSettings.cmake.in	681 B	-rw-r--r--
CMakeCCompiler.cmake.in	1.85 KB	-rw-r--r--
CMakeCCompilerABI.c	572 B	-rw-r--r--
CMakeCCompilerId.c.in	7.41 KB	-rw-r--r--
CMakeCInformation.cmake	7.56 KB	-rw-r--r--
CMakeCXXCompiler.cmake.in	2.01 KB	-rw-r--r--
CMakeCXXCompilerABI.cpp	450 B	-rw-r--r--
CMakeCXXCompilerId.cpp.in	7.32 KB	-rw-r--r--
CMakeCXXInformation.cmake	10.41 KB	-rw-r--r--
CMakeClDeps.cmake	1.64 KB	-rw-r--r--
CMakeCommonLanguageInclude.cma...	5.11 KB	-rw-r--r--
CMakeCompilerABI.h	1.18 KB	-rw-r--r--
CMakeConfigurableFile.in	35 B	-rw-r--r--
CMakeDependentOption.cmake	2.03 KB	-rw-r--r--
CMakeDetermineASM-ATTCompiler....	859 B	-rw-r--r--
CMakeDetermineASMCompiler.cmak...	7.24 KB	-rw-r--r--
CMakeDetermineASM_MASMCompiler...	942 B	-rw-r--r--
CMakeDetermineASM_NASMCompiler...	1011 B	-rw-r--r--
CMakeDetermineCCompiler.cmake	7.23 KB	-rw-r--r--
CMakeDetermineCXXCompiler.cmak...	7.31 KB	-rw-r--r--
CMakeDetermineCompiler.cmake	3.37 KB	-rw-r--r--
CMakeDetermineCompilerABI.cmak...	5.9 KB	-rw-r--r--
CMakeDetermineCompilerId.cmake	19.06 KB	-rw-r--r--
CMakeDetermineFortranCompiler....	9.94 KB	-rw-r--r--
CMakeDetermineJavaCompiler.cma...	4.13 KB	-rw-r--r--
CMakeDetermineRCCompiler.cmake	2.52 KB	-rw-r--r--
CMakeDetermineSystem.cmake	7.41 KB	-rw-r--r--
CMakeDetermineVSServicePack.cm...	6.6 KB	-rw-r--r--
CMakeExpandImportedTargets.cma...	5.77 KB	-rw-r--r--
CMakeExportBuildSettings.cmake	1.67 KB	-rw-r--r--
CMakeExtraGeneratorDetermineCo...	4.94 KB	-rw-r--r--
CMakeFindBinUtils.cmake	2.76 KB	-rw-r--r--
CMakeFindCodeBlocks.cmake	1.06 KB	-rw-r--r--
CMakeFindEclipseCDT4.cmake	4.65 KB	-rw-r--r--
CMakeFindFrameworks.cmake	1.16 KB	-rw-r--r--
CMakeFindKDevelop3.cmake	934 B	-rw-r--r--
CMakeFindPackageMode.cmake	6.2 KB	-rw-r--r--
CMakeFindWMake.cmake	737 B	-rw-r--r--
CMakeFindXCode.cmake	720 B	-rw-r--r--
CMakeForceCompiler.cmake	2.98 KB	-rw-r--r--
CMakeFortranCompiler.cmake.in	2.09 KB	-rw-r--r--
CMakeFortranCompilerABI.F	1023 B	-rw-r--r--
CMakeFortranCompilerId.F.in	4.38 KB	-rw-r--r--
CMakeFortranInformation.cmake	9.62 KB	-rw-r--r--
CMakeGenericSystem.cmake	6.66 KB	-rw-r--r--
CMakeGraphVizOptions.cmake	3 KB	-rw-r--r--
CMakeImportBuildSettings.cmake	1008 B	-rw-r--r--
CMakeJOMFindMake.cmake	736 B	-rw-r--r--
CMakeJavaCompiler.cmake.in	538 B	-rw-r--r--
CMakeJavaInformation.cmake	2.19 KB	-rw-r--r--
CMakeMSYSFindMake.cmake	954 B	-rw-r--r--
CMakeMinGWFindMake.cmake	1.24 KB	-rw-r--r--
CMakeNMakeFindMake.cmake	738 B	-rw-r--r--
CMakeNinjaFindMake.cmake	740 B	-rw-r--r--
CMakePackageConfigHelpers.cmak...	11.29 KB	-rw-r--r--
CMakeParseArguments.cmake	5.65 KB	-rw-r--r--
CMakeParseImplicitLinkInfo.cma...	6.88 KB	-rw-r--r--
CMakePlatformId.h.in	4.29 KB	-rw-r--r--
CMakePrintHelpers.cmake	4.32 KB	-rw-r--r--
CMakePrintSystemInformation.cm...	2.38 KB	-rw-r--r--
CMakePushCheckState.cmake	3.33 KB	-rw-r--r--
CMakeRCCompiler.cmake.in	267 B	-rw-r--r--
CMakeRCInformation.cmake	1.88 KB	-rw-r--r--
CMakeSystem.cmake.in	537 B	-rw-r--r--
CMakeSystemSpecificInformation...	2.79 KB	-rw-r--r--
CMakeTestASM-ATTCompiler.cmake	992 B	-rw-r--r--
CMakeTestASMCompiler.cmake	1.3 KB	-rw-r--r--
CMakeTestASM_MASMCompiler.cmak...	1021 B	-rw-r--r--
CMakeTestASM_NASMCompiler.cmak...	989 B	-rw-r--r--
CMakeTestCCompiler.cmake	3.52 KB	-rw-r--r--
CMakeTestCXXCompiler.cmake	3.41 KB	-rw-r--r--
CMakeTestCompilerCommon.cmake	894 B	-rw-r--r--
CMakeTestFortranCompiler.cmake	4.76 KB	-rw-r--r--
CMakeTestGNU.c	175 B	-rw-r--r--
CMakeTestJavaCompiler.cmake	950 B	-rw-r--r--
CMakeTestRCCompiler.cmake	1.01 KB	-rw-r--r--
CMakeTestWatcomVersion.c	20 B	-rw-r--r--
CMakeUnixFindMake.cmake	1.02 KB	-rw-r--r--
CMakeVS10FindMake.cmake	2.65 KB	-rw-r--r--
CMakeVS11FindMake.cmake	2.61 KB	-rw-r--r--
CMakeVS12FindMake.cmake	1.09 KB	-rw-r--r--
CMakeVS6BackwardCompatibility....	1.4 KB	-rw-r--r--
CMakeVS6FindMake.cmake	1 KB	-rw-r--r--
CMakeVS71FindMake.cmake	1.06 KB	-rw-r--r--
CMakeVS7BackwardCompatibility....	1.4 KB	-rw-r--r--
CMakeVS7FindMake.cmake	1021 B	-rw-r--r--
CMakeVS8FindMake.cmake	1.45 KB	-rw-r--r--
CMakeVS9FindMake.cmake	1.76 KB	-rw-r--r--
CMakeVerifyManifest.cmake	4.16 KB	-rw-r--r--
CPack.DS_Store.in	12 KB	-rw-r--r--
CPack.Description.plist.in	438 B	-rw-r--r--
CPack.Info.plist.in	1.1 KB	-rw-r--r--
CPack.OSXScriptLauncher.in	28.9 KB	-rw-r--r--
CPack.OSXScriptLauncher.rsrc.i...	362 B	-rw-r--r--
CPack.OSXX11.Info.plist.in	1.57 KB	-rw-r--r--
CPack.OSXX11.main.scpt.in	1.83 KB	-rw-r--r--
CPack.RuntimeScript.in	1.85 KB	-rw-r--r--
CPack.STGZ_Header.sh.in	3.76 KB	-rw-r--r--
CPack.VolumeIcon.icns.in	44.67 KB	-rw-r--r--
CPack.background.png.in	45.97 KB	-rw-r--r--
CPack.cmake	22.86 KB	-rw-r--r--
CPack.distribution.dist.in	448 B	-rw-r--r--
CPackBundle.cmake	1.77 KB	-rw-r--r--
CPackComponent.cmake	20.24 KB	-rw-r--r--
CPackCygwin.cmake	1.13 KB	-rw-r--r--
CPackDMG.cmake	2.66 KB	-rw-r--r--
CPackDeb.cmake	15.34 KB	-rw-r--r--
CPackNSIS.cmake	4.57 KB	-rw-r--r--
CPackPackageMaker.cmake	1.56 KB	-rw-r--r--
CPackRPM.cmake	42.01 KB	-rw-r--r--
CPackWIX.cmake	4.32 KB	-rw-r--r--
CPackZIP.cmake	1.42 KB	-rw-r--r--
CTest.cmake	9.7 KB	-rw-r--r--
CTestScriptMode.cmake	989 B	-rw-r--r--
CTestTargets.cmake	3.42 KB	-rw-r--r--
CTestUseLaunchers.cmake	2.7 KB	-rw-r--r--
CheckCCompilerFlag.cmake	2.9 KB	-rw-r--r--
CheckCSourceCompiles.cmake	3.45 KB	-rw-r--r--
CheckCSourceRuns.cmake	3.44 KB	-rw-r--r--
CheckCXXCompilerFlag.cmake	3.07 KB	-rw-r--r--
CheckCXXSourceCompiles.cmake	3.48 KB	-rw-r--r--
CheckCXXSourceRuns.cmake	3.46 KB	-rw-r--r--
CheckCXXSymbolExists.cmake	1.94 KB	-rw-r--r--
CheckForPthreads.c	701 B	-rw-r--r--
CheckFortranFunctionExists.cma...	2.49 KB	-rw-r--r--
CheckFunctionExists.c	380 B	-rw-r--r--
CheckFunctionExists.cmake	2.97 KB	-rw-r--r--
CheckIncludeFile.c.in	130 B	-rw-r--r--
CheckIncludeFile.cmake	3.03 KB	-rw-r--r--
CheckIncludeFile.cxx.in	65 B	-rw-r--r--
CheckIncludeFileCXX.cmake	3.05 KB	-rw-r--r--
CheckIncludeFiles.cmake	3.47 KB	-rw-r--r--
CheckLanguage.cmake	2.64 KB	-rw-r--r--
CheckLibraryExists.cmake	2.79 KB	-rw-r--r--
CheckLibraryExists.lists.in	298 B	-rw-r--r--
CheckPrototypeDefinition.c.in	514 B	-rw-r--r--
CheckPrototypeDefinition.cmake	4.04 KB	-rw-r--r--
CheckSizeOf.cmake	813 B	-rw-r--r--
CheckStructHasMember.cmake	1.77 KB	-rw-r--r--
CheckSymbolExists.cmake	4.16 KB	-rw-r--r--
CheckTypeSize.c.in	801 B	-rw-r--r--
CheckTypeSize.cmake	7.47 KB	-rw-r--r--
CheckTypeSizeMap.cmake.in	31 B	-rw-r--r--
CheckVariableExists.c	363 B	-rw-r--r--
CheckVariableExists.cmake	2.47 KB	-rw-r--r--
Dart.cmake	4.06 KB	-rw-r--r--
DartConfiguration.tcl.in	2.74 KB	-rw-r--r--
DeployQt4.cmake	13.19 KB	-rw-r--r--
Documentation.cmake	1.45 KB	-rw-r--r--
DummyCXXFile.cxx	27 B	-rw-r--r--
ExternalData.cmake	29.97 KB	-rw-r--r--
ExternalData_config.cmake.in	268 B	-rw-r--r--
ExternalProject.cmake	61.48 KB	-rw-r--r--
FLTKCompatibility.cmake	635 B	-rw-r--r--
FeatureSummary.cmake	19.38 KB	-rw-r--r--
FindALSA.cmake	2.14 KB	-rw-r--r--
FindASPELL.cmake	1.47 KB	-rw-r--r--
FindAVIFile.cmake	1.74 KB	-rw-r--r--
FindArmadillo.cmake	3.82 KB	-rw-r--r--
FindBISON.cmake	7.11 KB	-rw-r--r--
FindBLAS.cmake	16.39 KB	-rw-r--r--
FindBZip2.cmake	2.38 KB	-rw-r--r--
FindBoost.cmake	48.76 KB	-rw-r--r--
FindBullet.cmake	3.18 KB	-rw-r--r--
FindCABLE.cmake	2.84 KB	-rw-r--r--
FindCUDA.cmake	65.86 KB	-rw-r--r--
FindCURL.cmake	2.29 KB	-rw-r--r--
FindCVS.cmake	2.18 KB	-rw-r--r--
FindCoin3D.cmake	2.67 KB	-rw-r--r--
FindCups.cmake	2.91 KB	-rw-r--r--
FindCurses.cmake	6.57 KB	-rw-r--r--
FindCxxTest.cmake	7.61 KB	-rw-r--r--
FindCygwin.cmake	924 B	-rw-r--r--
FindDCMTK.cmake	4.44 KB	-rw-r--r--
FindDart.cmake	1.32 KB	-rw-r--r--
FindDevIL.cmake	2.82 KB	-rw-r--r--
FindDoxygen.cmake	5.05 KB	-rw-r--r--
FindEXPAT.cmake	2.37 KB	-rw-r--r--
FindFLEX.cmake	6.27 KB	-rw-r--r--
FindFLTK.cmake	11.1 KB	-rw-r--r--
FindFLTK2.cmake	9.01 KB	-rw-r--r--
FindFreetype.cmake	5.08 KB	-rw-r--r--
FindGCCXML.cmake	960 B	-rw-r--r--
FindGDAL.cmake	3.26 KB	-rw-r--r--
FindGIF.cmake	2.66 KB	-rw-r--r--
FindGLEW.cmake	1.27 KB	-rw-r--r--
FindGLU.cmake	1020 B	-rw-r--r--
FindGLUT.cmake	3.01 KB	-rw-r--r--
FindGTK.cmake	4.11 KB	-rw-r--r--
FindGTK2.cmake	22.83 KB	-rw-r--r--
FindGTest.cmake	5.41 KB	-rw-r--r--
FindGettext.cmake	8.1 KB	-rw-r--r--
FindGit.cmake	2.06 KB	-rw-r--r--
FindGnuTLS.cmake	2.37 KB	-rw-r--r--
FindGnuplot.cmake	1.96 KB	-rw-r--r--
FindHDF5.cmake	14.34 KB	-rw-r--r--
FindHSPELL.cmake	2.04 KB	-rw-r--r--
FindHTMLHelp.cmake	1.8 KB	-rw-r--r--
FindHg.cmake	1.79 KB	-rw-r--r--
FindITK.cmake	2.19 KB	-rw-r--r--
FindIcotool.cmake	1.66 KB	-rw-r--r--
FindImageMagick.cmake	9.96 KB	-rw-r--r--
FindJNI.cmake	9.93 KB	-rw-r--r--
FindJPEG.cmake	1.57 KB	-rw-r--r--
FindJasper.cmake	2.16 KB	-rw-r--r--
FindJava.cmake	7.83 KB	-rw-r--r--
FindKDE3.cmake	10.27 KB	-rw-r--r--
FindKDE4.cmake	3.48 KB	-rw-r--r--
FindLAPACK.cmake	9.28 KB	-rw-r--r--
FindLATEX.cmake	3.24 KB	-rw-r--r--
FindLibArchive.cmake	2.87 KB	-rw-r--r--
FindLibLZMA.cmake	3.53 KB	-rw-r--r--
FindLibXml2.cmake	2.67 KB	-rw-r--r--
FindLibXslt.cmake	2.86 KB	-rw-r--r--
FindLua50.cmake	2.75 KB	-rw-r--r--
FindLua51.cmake	2.58 KB	-rw-r--r--
FindLua52.cmake	2.2 KB	-rw-r--r--
FindMFC.cmake	2.24 KB	-rw-r--r--
FindMPEG.cmake	1.62 KB	-rw-r--r--
FindMPEG2.cmake	1.88 KB	-rw-r--r--
FindMPI.cmake	29.25 KB	-rw-r--r--
FindMatlab.cmake	3.39 KB	-rw-r--r--
FindMotif.cmake	1.29 KB	-rw-r--r--
FindOpenAL.cmake	3.85 KB	-rw-r--r--
FindOpenGL.cmake	5.29 KB	-rw-r--r--
FindOpenMP.cmake	5.3 KB	-rw-r--r--
FindOpenSSL.cmake	9.44 KB	-rw-r--r--
FindOpenSceneGraph.cmake	7.26 KB	-rw-r--r--
FindOpenThreads.cmake	4.16 KB	-rw-r--r--
FindPHP4.cmake	2.48 KB	-rw-r--r--
FindPNG.cmake	4.29 KB	-rw-r--r--
FindPackageHandleStandardArgs....	13.01 KB	-rw-r--r--
FindPackageMessage.cmake	1.92 KB	-rw-r--r--
FindPerl.cmake	3.03 KB	-rw-r--r--
FindPerlLibs.cmake	8.08 KB	-rw-r--r--
FindPhysFS.cmake	1.61 KB	-rw-r--r--
FindPike.cmake	1.19 KB	-rw-r--r--
FindPkgConfig.cmake	14.5 KB	-rw-r--r--
FindPostgreSQL.cmake	7.57 KB	-rw-r--r--
FindProducer.cmake	2.7 KB	-rw-r--r--
FindProtobuf.cmake	7.89 KB	-rw-r--r--
FindPythonInterp.cmake	6.07 KB	-rw-r--r--
FindPythonLibs.cmake	11.29 KB	-rw-r--r--
FindQt.cmake	6.07 KB	-rw-r--r--
FindQt3.cmake	9.48 KB	-rw-r--r--
FindQt4.cmake	59.73 KB	-rw-r--r--
FindQuickTime.cmake	1.39 KB	-rw-r--r--
FindRTI.cmake	3.57 KB	-rw-r--r--
FindRuby.cmake	9.85 KB	-rw-r--r--
FindSDL.cmake	7.24 KB	-rw-r--r--
FindSDL_image.cmake	3.88 KB	-rw-r--r--
FindSDL_mixer.cmake	3.88 KB	-rw-r--r--
FindSDL_net.cmake	3.74 KB	-rw-r--r--
FindSDL_sound.cmake	13.48 KB	-rw-r--r--
FindSDL_ttf.cmake	3.74 KB	-rw-r--r--
FindSWIG.cmake	2.89 KB	-rw-r--r--
FindSelfPackers.cmake	1.84 KB	-rw-r--r--
FindSquish.cmake	10.14 KB	-rw-r--r--
FindSubversion.cmake	5.65 KB	-rw-r--r--
FindTCL.cmake	7.97 KB	-rw-r--r--
FindTIFF.cmake	1.92 KB	-rw-r--r--
FindTclStub.cmake	4.73 KB	-rw-r--r--
FindTclsh.cmake	3.74 KB	-rw-r--r--
FindThreads.cmake	5.84 KB	-rw-r--r--
FindUnixCommands.cmake	1.48 KB	-rw-r--r--
FindVTK.cmake	5.78 KB	-rw-r--r--
FindWget.cmake	1.26 KB	-rw-r--r--
FindWish.cmake	3.01 KB	-rw-r--r--
FindX11.cmake	20.05 KB	-rw-r--r--
FindXMLRPC.cmake	4.97 KB	-rw-r--r--
FindZLIB.cmake	3.58 KB	-rw-r--r--
Findosg.cmake	2.21 KB	-rw-r--r--
FindosgAnimation.cmake	2.17 KB	-rw-r--r--
FindosgDB.cmake	2.08 KB	-rw-r--r--
FindosgFX.cmake	2.08 KB	-rw-r--r--
FindosgGA.cmake	2.09 KB	-rw-r--r--
FindosgIntrospection.cmake	2.26 KB	-rw-r--r--
FindosgManipulator.cmake	2.24 KB	-rw-r--r--
FindosgParticle.cmake	2.17 KB	-rw-r--r--
FindosgPresentation.cmake	2.33 KB	-rw-r--r--
FindosgProducer.cmake	2.18 KB	-rw-r--r--
FindosgQt.cmake	2.14 KB	-rw-r--r--
FindosgShadow.cmake	2.14 KB	-rw-r--r--
FindosgSim.cmake	2.09 KB	-rw-r--r--
FindosgTerrain.cmake	2.15 KB	-rw-r--r--
FindosgText.cmake	2.09 KB	-rw-r--r--
FindosgUtil.cmake	2.1 KB	-rw-r--r--
FindosgViewer.cmake	2.13 KB	-rw-r--r--
FindosgVolume.cmake	2.13 KB	-rw-r--r--
FindosgWidget.cmake	2.18 KB	-rw-r--r--
Findosg_functions.cmake	3.05 KB	-rw-r--r--
FindwxWidgets.cmake	36.04 KB	-rw-r--r--
FindwxWindows.cmake	24.15 KB	-rw-r--r--
FortranCInterface.cmake	12.16 KB	-rw-r--r--
GNUInstallDirs.cmake	7.18 KB	-rw-r--r--
GenerateExportHeader.cmake	12.41 KB	-rw-r--r--
GetPrerequisites.cmake	28.59 KB	-rw-r--r--
ITKCompatibility.cmake	689 B	-rw-r--r--
InstallRequiredSystemLibraries...	14.93 KB	-rw-r--r--
KDE3Macros.cmake	13.26 KB	-rw-r--r--
MacOSXBundleInfo.plist.in	1.22 KB	-rw-r--r--
MacOSXFrameworkInfo.plist.in	886 B	-rw-r--r--
MacroAddFileDependencies.cmake	1.29 KB	-rw-r--r--
NSIS.InstallOptions.ini.in	678 B	-rw-r--r--
NSIS.template.in	27.82 KB	-rw-r--r--
ProcessorCount.cmake	6.84 KB	-rw-r--r--
Qt4ConfigDependentSettings.cma...	7.9 KB	-rw-r--r--
Qt4Macros.cmake	18.11 KB	-rw-r--r--
RepositoryInfo.txt.in	56 B	-rw-r--r--
SelectLibraryConfigurations.cm...	3.39 KB	-rw-r--r--
Squish4RunTestCase.bat	629 B	-rw-r--r--
Squish4RunTestCase.sh	773 B	-rw-r--r--
SquishRunTestCase.bat	219 B	-rw-r--r--
SquishRunTestCase.sh	272 B	-rw-r--r--
SquishTestScript.cmake	3.8 KB	-rw-r--r--
SystemInformation.cmake	3.57 KB	-rw-r--r--
SystemInformation.in	4.59 KB	-rw-r--r--
TestBigEndian.cmake	4.51 KB	-rw-r--r--
TestCXXAcceptsFlag.cmake	1.78 KB	-rw-r--r--
TestEndianess.c.in	871 B	-rw-r--r--
TestForANSIForScope.cmake	1.77 KB	-rw-r--r--
TestForANSIStreamHeaders.cmake	1.29 KB	-rw-r--r--
TestForANSIStreamHeaders.cxx	60 B	-rw-r--r--
TestForAnsiForScope.cxx	87 B	-rw-r--r--
TestForSSTREAM.cmake	1.74 KB	-rw-r--r--
TestForSSTREAM.cxx	154 B	-rw-r--r--
TestForSTDNamespace.cmake	1.69 KB	-rw-r--r--
TestForSTDNamespace.cxx	75 B	-rw-r--r--
UseEcos.cmake	10.1 KB	-rw-r--r--
UseJava.cmake	35.32 KB	-rw-r--r--
UseJavaClassFilelist.cmake	2.13 KB	-rw-r--r--
UseJavaSymlinks.cmake	1.09 KB	-rw-r--r--
UsePkgConfig.cmake	2.95 KB	-rw-r--r--
UseQt4.cmake	2.96 KB	-rw-r--r--
UseSWIG.cmake	9.97 KB	-rw-r--r--
UseVTK40.cmake	1.14 KB	-rw-r--r--
UseVTKBuildSettings40.cmake	1.89 KB	-rw-r--r--
UseVTKConfig40.cmake	13.12 KB	-rw-r--r--
Use_wxWindows.cmake	2.37 KB	-rw-r--r--
UsewxWidgets.cmake	3.17 KB	-rw-r--r--
VTKCompatibility.cmake	2.13 KB	-rw-r--r--
WIX.template.in	1.47 KB	-rw-r--r--
WriteBasicConfigVersionFile.cm...	1.72 KB	-rw-r--r--
ecos_clean.cmake	968 B	-rw-r--r--
exportheader.cmake.in	911 B	-rw-r--r--
kde3init_dummy.cpp.in	227 B	-rw-r--r--
kde3uic.cmake	1.21 KB	-rw-r--r--
readme.txt	9.1 KB	-rw-r--r--

Code Editor : CPack.cmake

##section Variables common to all CPack generators
##end
##module
# - Build binary and source package installers.
# The CPack module generates binary and source installers in a variety
# of formats using the cpack program. Inclusion of the CPack module
# adds two new targets to the resulting makefiles, package and
# package_source, which build the binary and source installers,
# respectively. The generated binary installers contain everything
# installed via CMake's INSTALL command (and the deprecated
# INSTALL_FILES, INSTALL_PROGRAMS, and INSTALL_TARGETS commands).
#
# For certain kinds of binary installers (including the graphical
# installers on Mac OS X and Windows), CPack generates installers that
# allow users to select individual application components to
# install. See CPackComponent module for that.
#
# The CPACK_GENERATOR variable has different meanings in different
# contexts. In your CMakeLists.txt file, CPACK_GENERATOR is a
# *list of generators*: when run with no other arguments, CPack
# will iterate over that list and produce one package for each
# generator. In a CPACK_PROJECT_CONFIG_FILE, though, CPACK_GENERATOR
# is a *string naming a single generator*. If you need per-cpack-
# generator logic to control *other* cpack settings, then you need
# a CPACK_PROJECT_CONFIG_FILE.
#
# The CMake source tree itself contains a CPACK_PROJECT_CONFIG_FILE.
# See the top level file CMakeCPackOptions.cmake.in for an example.
#
# If set, the CPACK_PROJECT_CONFIG_FILE is included automatically
# on a per-generator basis. It only need contain overrides.
#
# Here's how it works:
#  - cpack runs
#  - it includes CPackConfig.cmake
#  - it iterates over the generators listed in that file's
#    CPACK_GENERATOR list variable (unless told to use just a
#    specific one via -G on the command line...)
#
#  - foreach generator, it then
#    - sets CPACK_GENERATOR to the one currently being iterated
#    - includes the CPACK_PROJECT_CONFIG_FILE
#    - produces the package for that generator
#
# This is the key: For each generator listed in CPACK_GENERATOR
# in CPackConfig.cmake, cpack will *reset* CPACK_GENERATOR
# internally to *the one currently being used* and then include
# the CPACK_PROJECT_CONFIG_FILE.
#
# Before including this CPack module in your CMakeLists.txt file,
# there are a variety of variables that can be set to customize
# the resulting installers. The most commonly-used variables are:
##end
#
##variable
#  CPACK_PACKAGE_NAME - The name of the package (or application). If
#  not specified, defaults to the project name.
##end
#
##variable
#  CPACK_PACKAGE_VENDOR - The name of the package vendor. (e.g.,
#  "Kitware").
##end
#
##variable
#  CPACK_PACKAGE_DIRECTORY - The directory in which CPack is doing its
#  packaging. If it is not set then this will default (internally) to the
#  build dir. This variable may be defined in CPack config file or from
#  the cpack command line option "-B". If set the command line option
#  override the value found in the config file.
##end
#
##variable
#  CPACK_PACKAGE_VERSION_MAJOR - Package major Version
##end
#
##variable
#  CPACK_PACKAGE_VERSION_MINOR - Package minor Version
##end
#
##variable
#  CPACK_PACKAGE_VERSION_PATCH - Package patch Version
##end
#
##variable
#  CPACK_PACKAGE_DESCRIPTION_FILE - A text file used to describe the
#  project. Used, for example, the introduction screen of a
#  CPack-generated Windows installer to describe the project.
##end
#
##variable
#  CPACK_PACKAGE_DESCRIPTION_SUMMARY - Short description of the
#  project (only a few words).
##end
#
##variable
#  CPACK_PACKAGE_FILE_NAME - The name of the package file to generate,
#  not including the extension. For example, cmake-2.6.1-Linux-i686.
#  The default value is
#
#  ${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}-${CPACK_SYSTEM_NAME}.
##end
#
##variable
#  CPACK_PACKAGE_INSTALL_DIRECTORY - Installation directory on the
#  target system. This may be used by some CPack generators
#  like NSIS to create an installation directory e.g., "CMake 2.5"
#  below the installation prefix. All installed element will be
#  put inside this directory.
##end
#
##variable
#   CPACK_PACKAGE_ICON - A branding image that will be displayed inside
#   the installer (used by GUI installers).
##end
#
##variable
#  CPACK_PROJECT_CONFIG_FILE - CPack-time project CPack configuration
#  file. This file included at cpack time, once per
#  generator after CPack has set CPACK_GENERATOR to the actual generator
#  being used. It allows per-generator setting of CPACK_* variables at
#  cpack time.
##end
#
##variable
#  CPACK_RESOURCE_FILE_LICENSE - License to be embedded in the installer. It
#  will typically be displayed to the user by the produced installer
#  (often with an explicit "Accept" button, for graphical installers)
#  prior to installation. This license file is NOT added to installed
#  file but is used by some CPack generators like NSIS. If you want
#  to install a license file (may be the same as this one)
#  along with your project you must add an appropriate CMake INSTALL
#  command in your CMakeLists.txt.
##end
#
##variable
#  CPACK_RESOURCE_FILE_README - ReadMe file to be embedded in the installer. It
#  typically describes in some detail the purpose of the project
#  during the installation. Not all CPack generators uses
#  this file.
##end
#
##variable
#  CPACK_RESOURCE_FILE_WELCOME - Welcome file to be embedded in the
#  installer. It welcomes users to this installer.
#  Typically used in the graphical installers on Windows and Mac OS X.
##end
#
##variable
#  CPACK_MONOLITHIC_INSTALL - Disables the component-based
#  installation mechanism. When set the component specification is ignored
#  and all installed items are put in a single "MONOLITHIC" package.
#  Some CPack generators do monolithic packaging by default and
#  may be asked to do component packaging by setting
#  CPACK_<GENNAME>_COMPONENT_INSTALL to 1/TRUE.
##end
#
##variable
#  CPACK_GENERATOR - List of CPack generators to use. If not
#  specified, CPack will create a set of options CPACK_BINARY_<GENNAME> (e.g.,
#  CPACK_BINARY_NSIS) allowing the user to enable/disable individual
#  generators. This variable may be used on the command line
#  as well as in:
#
#    cpack -D CPACK_GENERATOR="ZIP;TGZ" /path/to/build/tree
##end
#
##variable
#  CPACK_OUTPUT_CONFIG_FILE - The name of the CPack binary configuration
#  file. This file is the CPack configuration generated by the CPack module
#  for binary installers. Defaults to CPackConfig.cmake.
##end
#
##variable
#  CPACK_PACKAGE_EXECUTABLES - Lists each of the executables and associated
#  text label to be used to create Start Menu shortcuts. For example,
#  setting this to the list ccmake;CMake will
#  create a shortcut named "CMake" that will execute the installed
#  executable ccmake. Not all CPack generators use it (at least NSIS and
#  OSXX11 do).
##end
#
##variable
#  CPACK_STRIP_FILES - List of files to be stripped. Starting with
#  CMake 2.6.0 CPACK_STRIP_FILES will be a boolean variable which
#  enables stripping of all files (a list of files evaluates to TRUE
#  in CMake, so this change is compatible).
##end
#
# The following CPack variables are specific to source packages, and
# will not affect binary packages:
#
##variable
#  CPACK_SOURCE_PACKAGE_FILE_NAME - The name of the source package. For
#  example cmake-2.6.1.
##end
#
##variable
#  CPACK_SOURCE_STRIP_FILES - List of files in the source tree that
#  will be stripped. Starting with CMake 2.6.0
#  CPACK_SOURCE_STRIP_FILES will be a boolean variable which enables
#  stripping of all files (a list of files evaluates to TRUE in CMake,
#  so this change is compatible).
##end
#
##variable
#  CPACK_SOURCE_GENERATOR - List of generators used for the source
#  packages. As with CPACK_GENERATOR, if this is not specified then
#  CPack will create a set of options (e.g., CPACK_SOURCE_ZIP)
#  allowing users to select which packages will be generated.
##end
#
##variable
#  CPACK_SOURCE_OUTPUT_CONFIG_FILE - The name of the CPack source
#  configuration file. This file is the CPack configuration generated by the
#  CPack module for source installers. Defaults to CPackSourceConfig.cmake.
##end
#
##variable
#  CPACK_SOURCE_IGNORE_FILES - Pattern of files in the source tree
#  that won't be packaged when building a source package. This is a
#  list of regular expression patterns (that must be properly escaped),
#  e.g., /CVS/;/\\.svn/;\\.swp$;\\.#;/#;.*~;cscope.*
##end
#
# The following variables are for advanced uses of CPack:
#
##variable
#  CPACK_CMAKE_GENERATOR - What CMake generator should be used if the
#  project is CMake project. Defaults to the value of CMAKE_GENERATOR
#  few users will want to change this setting.
##end
#
##variable
#  CPACK_INSTALL_CMAKE_PROJECTS - List of four values that specify
#  what project to install. The four values are: Build directory,
#  Project Name, Project Component, Directory. If omitted, CPack will
#  build an installer that installers everything.
##end
#
##variable
#  CPACK_SYSTEM_NAME - System name, defaults to the value of
#  ${CMAKE_SYSTEM_NAME}.
##end
#
##variable
#  CPACK_PACKAGE_VERSION - Package full version, used internally. By
#  default, this is built from CPACK_PACKAGE_VERSION_MAJOR,
#  CPACK_PACKAGE_VERSION_MINOR, and CPACK_PACKAGE_VERSION_PATCH.
##end
#
##variable
#  CPACK_TOPLEVEL_TAG - Directory for the installed files.
##end
#
##variable
#  CPACK_INSTALL_COMMANDS - Extra commands to install components.
##end
#
##variable
#  CPACK_INSTALLED_DIRECTORIES - Extra directories to install.
##end
#
##variable
#   CPACK_PACKAGE_INSTALL_REGISTRY_KEY - Registry key used when
#   installing this project. This is only used by installer for Windows.
#   The default value is based on the installation directory.
##end
##variable
#   CPACK_CREATE_DESKTOP_LINKS - List of desktop links to create.
##end
#

#=============================================================================
# Copyright 2006-2009 Kitware, Inc.
#
# Distributed under the OSI-approved BSD License (the "License");
# see accompanying file Copyright.txt for details.
#
# This software is distributed WITHOUT ANY WARRANTY; without even the
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
# See the License for more information.
#=============================================================================
# (To distribute this file outside of CMake, substitute the full
#  License text for the above reference.)

# Define this var in order to avoid (or warn) concerning multiple inclusion
if(CPack_CMake_INCLUDED)
  message(WARNING "CPack.cmake has already been included!!")
else()
  set(CPack_CMake_INCLUDED 1)
endif()

# Pick a configuration file
set(cpack_input_file "${CMAKE_ROOT}/Templates/CPackConfig.cmake.in")
if(EXISTS "${CMAKE_SOURCE_DIR}/CPackConfig.cmake.in")
  set(cpack_input_file "${CMAKE_SOURCE_DIR}/CPackConfig.cmake.in")
endif()
set(cpack_source_input_file "${CMAKE_ROOT}/Templates/CPackConfig.cmake.in")
if(EXISTS "${CMAKE_SOURCE_DIR}/CPackSourceConfig.cmake.in")
  set(cpack_source_input_file "${CMAKE_SOURCE_DIR}/CPackSourceConfig.cmake.in")
endif()

# Backward compatibility
# Include CPackComponent macros if it has not already been included before.
include(CPackComponent)

# Macro for setting values if a user did not overwrite them
macro(cpack_set_if_not_set name value)
  if(NOT DEFINED "${name}")
    set(${name} "${value}")
  endif()
endmacro()

# cpack_encode_variables - Macro to encode variables for the configuration file
# find any variable that starts with CPACK and create a variable
# _CPACK_OTHER_VARIABLES_ that contains SET commands for
# each cpack variable.  _CPACK_OTHER_VARIABLES_ is then
# used as an @ replacment in configure_file for the CPackConfig.
macro(cpack_encode_variables)
  set(_CPACK_OTHER_VARIABLES_)
  get_cmake_property(res VARIABLES)
  foreach(var ${res})
    if("xxx${var}" MATCHES "xxxCPACK")
      set(_CPACK_OTHER_VARIABLES_
        "${_CPACK_OTHER_VARIABLES_}\nSET(${var} \"${${var}}\")")
      endif()
  endforeach()
endmacro()

# Set the package name
cpack_set_if_not_set(CPACK_PACKAGE_NAME "${CMAKE_PROJECT_NAME}")
cpack_set_if_not_set(CPACK_PACKAGE_VERSION_MAJOR "0")
cpack_set_if_not_set(CPACK_PACKAGE_VERSION_MINOR "1")
cpack_set_if_not_set(CPACK_PACKAGE_VERSION_PATCH "1")
cpack_set_if_not_set(CPACK_PACKAGE_VERSION
  "${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
cpack_set_if_not_set(CPACK_PACKAGE_VENDOR "Humanity")
cpack_set_if_not_set(CPACK_PACKAGE_DESCRIPTION_SUMMARY
  "${CMAKE_PROJECT_NAME} built using CMake")

cpack_set_if_not_set(CPACK_PACKAGE_DESCRIPTION_FILE
  "${CMAKE_ROOT}/Templates/CPack.GenericDescription.txt")
cpack_set_if_not_set(CPACK_RESOURCE_FILE_LICENSE
  "${CMAKE_ROOT}/Templates/CPack.GenericLicense.txt")
cpack_set_if_not_set(CPACK_RESOURCE_FILE_README
  "${CMAKE_ROOT}/Templates/CPack.GenericDescription.txt")
cpack_set_if_not_set(CPACK_RESOURCE_FILE_WELCOME
  "${CMAKE_ROOT}/Templates/CPack.GenericWelcome.txt")

cpack_set_if_not_set(CPACK_MODULE_PATH "${CMAKE_MODULE_PATH}")

if(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL)
  set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL ON)
endif()

if(CPACK_NSIS_MODIFY_PATH)
  set(CPACK_NSIS_MODIFY_PATH ON)
endif()

set(__cpack_system_name ${CMAKE_SYSTEM_NAME})
if(${__cpack_system_name} MATCHES Windows)
  if(CMAKE_CL_64)
    set(__cpack_system_name win64)
  else()
    set(__cpack_system_name win32)
  endif()
endif()
cpack_set_if_not_set(CPACK_SYSTEM_NAME "${__cpack_system_name}")

# Root dir: default value should be the string literal "$PROGRAMFILES"
# for backwards compatibility. Projects may set this value to anything.
set(__cpack_root_default "$PROGRAMFILES")
cpack_set_if_not_set(CPACK_NSIS_INSTALL_ROOT "${__cpack_root_default}")

# <project>-<major>.<minor>.<patch>-<release>-<platform>.<pkgtype>
cpack_set_if_not_set(CPACK_PACKAGE_FILE_NAME
  "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}-${CPACK_SYSTEM_NAME}")
cpack_set_if_not_set(CPACK_PACKAGE_INSTALL_DIRECTORY
  "${CPACK_PACKAGE_NAME} ${CPACK_PACKAGE_VERSION}")
cpack_set_if_not_set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY
  "${CPACK_PACKAGE_INSTALL_DIRECTORY}")
cpack_set_if_not_set(CPACK_PACKAGE_DEFAULT_LOCATION "/")
cpack_set_if_not_set(CPACK_PACKAGE_RELOCATABLE "true")

# always force to exactly "true" or "false" for CPack.Info.plist.in:
if(CPACK_PACKAGE_RELOCATABLE)
  set(CPACK_PACKAGE_RELOCATABLE "true")
else()
  set(CPACK_PACKAGE_RELOCATABLE "false")
endif()

macro(cpack_check_file_exists file description)
  if(NOT EXISTS "${file}")
    message(SEND_ERROR "CPack ${description} file: \"${file}\" could not be found.")
  endif()
endmacro()

cpack_check_file_exists("${CPACK_PACKAGE_DESCRIPTION_FILE}" "package description")
cpack_check_file_exists("${CPACK_RESOURCE_FILE_LICENSE}"    "license resource")
cpack_check_file_exists("${CPACK_RESOURCE_FILE_README}"     "readme resource")
cpack_check_file_exists("${CPACK_RESOURCE_FILE_WELCOME}"    "welcome resource")

macro(cpack_optional_append _list _cond _item)
  if(${_cond})
    set(${_list} ${${_list}} ${_item})
  endif()
endmacro()

##variable
# CPACK_BINARY_<GENNAME> - CPack generated options for binary generators. The
# CPack.cmake module generates (when CPACK_GENERATOR is not set)
# a set of CMake options (see CMake option command) which may then be used to
# select the CPack generator(s) to be used when launching the package target.
##end
# Provide options to choose generators
# we might check here if the required tools for the generates exist
# and set the defaults according to the results
if(NOT CPACK_GENERATOR)
  if(UNIX)
    if(CYGWIN)
      option(CPACK_BINARY_CYGWIN "Enable to build Cygwin binary packages" ON)
    else()
      if(APPLE)
        option(CPACK_BINARY_BUNDLE       "Enable to build OSX bundles"      OFF)
        option(CPACK_BINARY_DRAGNDROP    "Enable to build OSX Drag And Drop package" OFF)
        option(CPACK_BINARY_PACKAGEMAKER "Enable to build PackageMaker packages" ON)
        option(CPACK_BINARY_OSXX11       "Enable to build OSX X11 packages"      OFF)
      else()
        option(CPACK_BINARY_TZ  "Enable to build TZ packages"     ON)
      endif()
      option(CPACK_BINARY_STGZ "Enable to build STGZ packages"    ON)
      option(CPACK_BINARY_TGZ  "Enable to build TGZ packages"     ON)
      option(CPACK_BINARY_TBZ2 "Enable to build TBZ2 packages"    OFF)
      option(CPACK_BINARY_DEB  "Enable to build Debian packages"  OFF)
      option(CPACK_BINARY_RPM  "Enable to build RPM packages"     OFF)
      option(CPACK_BINARY_NSIS "Enable to build NSIS packages"    OFF)
    endif()
  else()
    option(CPACK_BINARY_NSIS "Enable to build NSIS packages" ON)
    option(CPACK_BINARY_WIX  "Enable to build WiX packages" OFF)
    option(CPACK_BINARY_ZIP  "Enable to build ZIP packages" OFF)
  endif()

cpack_optional_append(CPACK_GENERATOR  CPACK_BINARY_BUNDLE       Bundle)
  cpack_optional_append(CPACK_GENERATOR  CPACK_BINARY_DRAGNDROP    DragNDrop)
  cpack_optional_append(CPACK_GENERATOR  CPACK_BINARY_PACKAGEMAKER PackageMaker)
  cpack_optional_append(CPACK_GENERATOR  CPACK_BINARY_OSXX11       OSXX11)
  cpack_optional_append(CPACK_GENERATOR  CPACK_BINARY_CYGWIN       CygwinBinary)
  cpack_optional_append(CPACK_GENERATOR  CPACK_BINARY_DEB          DEB)
  cpack_optional_append(CPACK_GENERATOR  CPACK_BINARY_RPM          RPM)
  cpack_optional_append(CPACK_GENERATOR  CPACK_BINARY_NSIS         NSIS)
  cpack_optional_append(CPACK_GENERATOR  CPACK_BINARY_STGZ         STGZ)
  cpack_optional_append(CPACK_GENERATOR  CPACK_BINARY_TGZ          TGZ)
  cpack_optional_append(CPACK_GENERATOR  CPACK_BINARY_TBZ2         TBZ2)
  cpack_optional_append(CPACK_GENERATOR  CPACK_BINARY_TZ           TZ)
  cpack_optional_append(CPACK_GENERATOR  CPACK_BINARY_WIX          WIX)
  cpack_optional_append(CPACK_GENERATOR  CPACK_BINARY_ZIP          ZIP)

endif()

# Provide options to choose source generators
if(NOT CPACK_SOURCE_GENERATOR)
  if(UNIX)
    if(CYGWIN)
      option(CPACK_SOURCE_CYGWIN "Enable to build Cygwin source packages" ON)
    else()
      option(CPACK_SOURCE_TBZ2 "Enable to build TBZ2 source packages" ON)
      option(CPACK_SOURCE_TGZ  "Enable to build TGZ source packages"  ON)
      option(CPACK_SOURCE_TZ   "Enable to build TZ source packages"   ON)
      option(CPACK_SOURCE_ZIP  "Enable to build ZIP source packages"  OFF)
    endif()
  else()
    option(CPACK_SOURCE_ZIP "Enable to build ZIP source packages" ON)
  endif()

cpack_optional_append(CPACK_SOURCE_GENERATOR  CPACK_SOURCE_CYGWIN  CygwinSource)
  cpack_optional_append(CPACK_SOURCE_GENERATOR  CPACK_SOURCE_TGZ     TGZ)
  cpack_optional_append(CPACK_SOURCE_GENERATOR  CPACK_SOURCE_TBZ2    TBZ2)
  cpack_optional_append(CPACK_SOURCE_GENERATOR  CPACK_SOURCE_TZ      TZ)
  cpack_optional_append(CPACK_SOURCE_GENERATOR  CPACK_SOURCE_ZIP     ZIP)
endif()

# mark the above options as advanced
mark_as_advanced(CPACK_BINARY_CYGWIN CPACK_BINARY_PACKAGEMAKER CPACK_BINARY_OSXX11
                 CPACK_BINARY_STGZ   CPACK_BINARY_TGZ          CPACK_BINARY_TBZ2
                 CPACK_BINARY_DEB    CPACK_BINARY_RPM          CPACK_BINARY_TZ
                 CPACK_BINARY_NSIS CPACK_BINARY_WIX CPACK_BINARY_ZIP CPACK_BINARY_BUNDLE
                 CPACK_SOURCE_CYGWIN CPACK_SOURCE_TBZ2 CPACK_SOURCE_TGZ
                 CPACK_SOURCE_TZ CPACK_SOURCE_ZIP CPACK_BINARY_DRAGNDROP)

# Set some other variables
cpack_set_if_not_set(CPACK_INSTALL_CMAKE_PROJECTS
  "${CMAKE_BINARY_DIR};${CMAKE_PROJECT_NAME};ALL;/")
cpack_set_if_not_set(CPACK_CMAKE_GENERATOR "${CMAKE_GENERATOR}")
cpack_set_if_not_set(CPACK_TOPLEVEL_TAG "${CPACK_SYSTEM_NAME}")
# if the user has set CPACK_NSIS_DISPLAY_NAME remember it
if(DEFINED CPACK_NSIS_DISPLAY_NAME)
  set(CPACK_NSIS_DISPLAY_NAME_SET TRUE)
endif()
# if the user has set CPACK_NSIS_DISPLAY
# explicitly, then use that as the default
# value of CPACK_NSIS_PACKAGE_NAME  instead
# of CPACK_PACKAGE_INSTALL_DIRECTORY
cpack_set_if_not_set(CPACK_NSIS_DISPLAY_NAME "${CPACK_PACKAGE_INSTALL_DIRECTORY}")

if(CPACK_NSIS_DISPLAY_NAME_SET)
  string(REPLACE "\\" "\\\\"
    _NSIS_DISPLAY_NAME_TMP  "${CPACK_NSIS_DISPLAY_NAME}")
  cpack_set_if_not_set(CPACK_NSIS_PACKAGE_NAME "${_NSIS_DISPLAY_NAME_TMP}")
else()
  cpack_set_if_not_set(CPACK_NSIS_PACKAGE_NAME "${CPACK_PACKAGE_INSTALL_DIRECTORY}")
endif()

cpack_set_if_not_set(CPACK_OUTPUT_CONFIG_FILE
  "${CMAKE_BINARY_DIR}/CPackConfig.cmake")

cpack_set_if_not_set(CPACK_SOURCE_OUTPUT_CONFIG_FILE
  "${CMAKE_BINARY_DIR}/CPackSourceConfig.cmake")

cpack_set_if_not_set(CPACK_SET_DESTDIR OFF)
cpack_set_if_not_set(CPACK_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}")

cpack_set_if_not_set(CPACK_NSIS_INSTALLER_ICON_CODE "")
cpack_set_if_not_set(CPACK_NSIS_INSTALLER_MUI_ICON_CODE "")

# WiX specific variables
cpack_set_if_not_set(CPACK_WIX_SIZEOF_VOID_P "${CMAKE_SIZEOF_VOID_P}")

if(DEFINED CPACK_COMPONENTS_ALL)
  if(CPACK_MONOLITHIC_INSTALL)
    message("CPack warning: both CPACK_COMPONENTS_ALL and CPACK_MONOLITHIC_INSTALL have been set.\nDefaulting to a monolithic installation.")
    set(CPACK_COMPONENTS_ALL)
  else()
    # The user has provided the set of components to be installed as
    # part of a component-based installation; trust her.
    set(CPACK_COMPONENTS_ALL_SET_BY_USER TRUE)
  endif()
else()
  # If the user has not specifically requested a monolithic installer
  # but has specified components in various "install" commands, tell
  # CPack about those components.
  if(NOT CPACK_MONOLITHIC_INSTALL)
    get_cmake_property(CPACK_COMPONENTS_ALL COMPONENTS)
    list(LENGTH CPACK_COMPONENTS_ALL CPACK_COMPONENTS_LEN)
    if(CPACK_COMPONENTS_LEN EQUAL 1)
      # Only one component: this is not a component-based installation
      # (at least, it isn't a component-based installation, but may
      # become one later if the user uses the cpack_add_* commands).
      set(CPACK_COMPONENTS_ALL)
    endif()
    set(CPACK_COMPONENTS_LEN)
  endif()
endif()

# CMake always generates a component named "Unspecified", which is
# used to install everything that doesn't have an explicitly-provided
# component. Since these files should always be installed, we'll make
# them hidden and required.
set(CPACK_COMPONENT_UNSPECIFIED_HIDDEN TRUE)
set(CPACK_COMPONENT_UNSPECIFIED_REQUIRED TRUE)

cpack_encode_variables()
configure_file("${cpack_input_file}" "${CPACK_OUTPUT_CONFIG_FILE}" @ONLY IMMEDIATE)

# Generate source file
cpack_set_if_not_set(CPACK_SOURCE_INSTALLED_DIRECTORIES
  "${CMAKE_SOURCE_DIR};/")
cpack_set_if_not_set(CPACK_SOURCE_TOPLEVEL_TAG "${CPACK_SYSTEM_NAME}-Source")
cpack_set_if_not_set(CPACK_SOURCE_PACKAGE_FILE_NAME
  "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}-Source")
cpack_set_if_not_set(CPACK_SOURCE_IGNORE_FILES
  "/CVS/;/\\\\\\\\.svn/;/\\\\\\\\.bzr/;/\\\\\\\\.hg/;/\\\\\\\\.git/;\\\\\\\\.swp$;\\\\\\\\.#;/#")
set(CPACK_INSTALL_CMAKE_PROJECTS "${CPACK_SOURCE_INSTALL_CMAKE_PROJECTS}")
set(CPACK_INSTALLED_DIRECTORIES "${CPACK_SOURCE_INSTALLED_DIRECTORIES}")
set(CPACK_GENERATOR "${CPACK_SOURCE_GENERATOR}")
set(CPACK_TOPLEVEL_TAG "${CPACK_SOURCE_TOPLEVEL_TAG}")
set(CPACK_PACKAGE_FILE_NAME "${CPACK_SOURCE_PACKAGE_FILE_NAME}")
set(CPACK_IGNORE_FILES "${CPACK_SOURCE_IGNORE_FILES}")
set(CPACK_STRIP_FILES "${CPACK_SOURCE_STRIP_FILES}")

cpack_encode_variables()
configure_file("${cpack_source_input_file}"
  "${CPACK_SOURCE_OUTPUT_CONFIG_FILE}" @ONLY IMMEDIATE)

${this.title}

Code Editor : CPack.cmake